JFP does not support SERIALIZE-NAME in JSDO catalog

When a JSON Filter Pattern (JFP) references a table with one or more fields defined with a hyphenated name and a non-hyphenated SERIALIZE-NAME,  errors (7328)  and (7211) are raised by the ABL Business Entity code processing the filter.

When a data service object is defined using a schema with SERIALIZE-NAME field attributes:
 

FIELD Cust-Num AS INTEGER INITIAL "0" LABEL "Cust Num" SERIALIZE-NAME "CustX"
FIELD Cust1 AS INTEGER INITIAL "0" LABEL "Cust1" SERIALIZE-NAME "Cust1X"

The serialize-name field value is displayed in the Kendo UI grid as a column.  But when trying to select the column heading to sort or filter the values the browser returns errors (7328) and (7211).
 

Following the workshop document "A Sexy UI for Progress OpenEdge using JSDO and KendoUI", modifying the sample code to add fields with SERIALIZE-NAME attributes.

The JSDO catalog (service.json file) is built using the field SERIALIZE-NAME attribute value. For example:

                                "CustX": {
                                    "type": "integer",
                                    "ablType": "INTEGER",
                                    "default": 0,
                                    "title": "Cust Num"
                                },
                                "Cust1X": {
                                    "type": "integer",
                                    "ablType": "INTEGER",
                                    "default": 0,
                                    "title": "Cust1"
                                }

The filter for the JSON Filter Pattern is constructed on the client side (JavaScript) and can only see the names from the JSDO catalog.  When the query is passed to the back end ABL code, the query fails because there isn't a field in the database table with the same value as the SERIALIZE-NAME attribute.

Upgrade to JSDO 4.3.1

Modify the ABL backend code to map the SERIALIZE-NAME attribute field values to their real database equivalents.  

1. In the Data Object service code, created a new method 'MapSerializeFields" to map the query SERIALIZE-NAME field name to the actual database field name:

    METHOD PUBLIC CHARACTER MapSerializeFields(INPUT filter AS CHARACTER):
        DEFINE VARIABLE result      AS CHARACTER NO-UNDO.
        DEFINE VARIABLE iorderBy    AS INTEGER   NO-UNDO.
        DEFINE VARIABLE cSortField  AS CHARACTER NO-UNDO. 
        DEFINE VARIABLE cSortString AS CHARACTER NO-UNDO. 
        DEFINE VARIABLE iComma      AS INTEGER   NO-UNDO.
        DEFINE VARIABLE hTT         AS HANDLE    NO-UNDO.
        DEFINE VARIABLE i           AS INTEGER   NO-UNDO.
        DEFINE VARIABLE hField      AS HANDLE    NO-UNDO.
        DEFINE VARIABLE cDBField    AS CHARACTER NO-UNDO.
        DEFINE VARIABLE iDesc       AS INTEGER   NO-UNDO INITIAL 0.
        
        ASSIGN
            iorderBy = INDEX(filter,'"orderBy":',1)
            result   = filter.
    
        IF iOrderBy > 0 THEN
        DO:
            /* Determine the field to sort on */ 
            iComma = INDEX(filter,",",iOrderBy).
            ASSIGN
                cSortString = SUBSTRING(filter,iorderBy + 11,iComma - 1 - (iorderBy + 11))
                cSortField  = SUBSTRING(filter,iorderBy + 11,iComma - 1 - (iorderBy + 11)).   
            
            /* Descending sort? */
            iDesc = INDEX(cSortField,"DESC",iOrderBy).
            
            IF iDesc > 0 THEN
                /* Remove DESC off the sort field so it can be used to search the field names */
                cSortField = SUBSTRING(cSortField,1,LENGTH(cSortField) - 5).   
            
            /* Determine if any of the fields have NAME and SERIALIZE-NAME attributes that differ */
            /* If there is such a field, is this the same as the one the query should sort on? */ 
            htt = TEMP-TABLE ttCustomer:DEFAULT-BUFFER-HANDLE.           
            DO i = 1 TO htt:NUM-FIELDS:
                hField = htt:BUFFER-FIELD(i).
                IF hField:NAME = hField:SERIALIZE-NAME THEN NEXT.
                /* Is this field the one to sort on? */
                IF hField:SERIALIZE-NAME = cSortField THEN
                DO: 
                    cDBField = hField:NAME.
                    IF iDesc > 0 THEN
                        cDBField = hField:NAME + " DESC".

                    result = REPLACE(filter,cSortString,cDBField).
                    LEAVE.
                END.
                ELSE
                DO:
                    NEXT.
                END.
            END.
        END.
        RETURN result.
    END METHOD.

2. In the Data Object service code, modified the ReadCustomer method to use 'MapSerializeFields":

METHOD PUBLIC VOID ReadCustomer(
        INPUT filter AS CHARACTER, 
        OUTPUT DATASET dsCustomer):
            
        DEFINE VARIABLE mappedFilter AS CHARACTER NO-UNDO.               
        
        mappedFilter = THIS-OBJECT:MapSerializeFields (INPUT filter).
        
        IF filter BEGINS "~{" THEN
        DO:
            /* THIS-OBJECT:JFPFillMethod (INPUT filter).*/
            THIS-OBJECT:JFPFillMethod (INPUT mappedfilter).
        END.
        ELSE 
        DO:
            BUFFER ttCustomer:HANDLE:BATCH-SIZE = 0.
            /* SUPER:ReadData(filter).*/
            SUPER:ReadData(mappedfilter).
        END.                  
    END METHOD.

The original workshop document and fixed data object code is attached.  

JSDO 4.3.1 is shipped with OpenEdge 11.6.3 and Kendo UI Builder 1.1. It may also be downloaded from GitHub at https://github.com/CloudDataObject/JSDO.

References to Other Documentation:

Progress Data Objects Guide and Reference, "Overview of Progress Data Objects, Services, and Catalogs : Run-time architecture and data access"
https://documentation.progress.com/output/pdo/#page/pdo%2Frun-time-architecture-and-data-access.html

Progress Developer Studio for OpenEdge Online Help, "Data Object overview : Tasks : Working with Data Objects : Defining Data Object resources"
https://documentation.progress.com/output/OpenEdge116/openedge116/#page/pdsoe/defining-data-object-resources.html

Progress Community: A Sexy UI for Progress OpenEdge using JSDO, OE Mobile Template and Kendo UI with sorting, filtering and paging
https://community.progress.com/community_groups/mobile/w/mobile/2568.a-sexy-ui-for-progress-openedge-using-jsdo-oe-mobile-template-and-kendo-ui-with-sorting-filtering-and-paging

Progress Articles:

 JSDO catalog generated with characters that are invalid for JavaScript