Error 3406 or 72 occurs when executing a static method in a class whose name matches, or is an abbreviation of, a database field name.
Error 3406 or 72 occurs when referring to a static property in a class whose name matches, or is an abbreviation of, a database field name.

If a class name matches or can be construed as an abbreviation for a database field name and a static member of that class is invoked, ambiguity errors occur.

Specifying a USING statement has no effect. 
Errors do not appear if the fully qualified name of the class is used.

Example #1
The following code executed in a session that is connected to a Sports2000 database will result in error 72:

** Cust is ambiguous with Invoice.CustNum and Customer.CustNum (72)
 

CLASS Demo.Cust:
  DEFINE PUBLIC STATIC PROPERTY StaticProp AS CHARACTER NO-UNDO
    GET.
    SET.
  
  DEFINE PUBLIC PROPERTY InstanceProp AS CHARACTER NO-UNDO
    GET.
    SET.
END CLASS.

/* Test.p */
USING Demo.Cust.
Demo.cust:StaticProp = "Testing".

MESSAGE Cust:StaticProp
    VIEW-AS ALERT-BOX INFO BUTTONS OK.

Example #2
The following code executed in a session that is connected to a database containing table with a field called "path" will result in error 3406:

Unknown attribute Combine used in widget:attribute phrase. (3406)
 

USING System.IO.Path FROM ASSEMBLY.

DEFINE VARIABLE cFileName AS CHARACTER NO-UNDO. 

cFileName = Path:Combine(Path:GetTempPath(), STRING (GUID) + '.xlsx') .

MESSAGE cFileName 
     VIEW-AS ALERT-BOX.

Example #3
Like in example 2, if the following class is compiled while connected to a sports2000 database (which has the field Customer.CreditLimit) that will raise:

Unknown attribute Combine used in widget:attribute phrase. (3406)
 

BLOCK-LEVEL ON ERROR UNDO, THROW.

CLASS CreditLimit: 
    
    DEFINE PUBLIC STATIC PROPERTY Test AS CreditLimit
    GET:
        IF NOT VALID-OBJECT(CreditLimit:Test)
        THEN ASSIGN CreditLimit:Test = NEW CreditLimit().
        RETURN CreditLimit:Test.
    END GET.
    SET.
 
END CLASS.

 

This is expected behavior.  References to static class members with identical, or abbreviations of, names to connected database fields will always result in an ambiguity error.

The behaviour comes down to precedence of variables and fields over classes. Since fields and variables predate classes, they are given precedence. If an abbreviated name is specified, e.g. "Cust", precedence is given to finding fields that match the name Cust, e.g. CustNum. As a result, if a field name match is found, the compiler does not even look at static member names of classes. If precedence was given to classes then many existing ABL applications would fail to compile.
 

Ensure that no static class members match database field names, or are abbreviations of the same.

There is an idea on the community to add a new feature to address this problem at:

https://community.progress.com/community_groups/products_enhancements/i/openedge/do_not_allow_possible_abbreviated_table_and_field_names_to_take_priority_over_class_names
 

Use the fully qualified name of the class in the static method reference. 
If the issue is seen when a class refers to it's own methods or properties, as in Example 3, another option is to remove the class name from the reference altogether.

Using the examples above:

Example #1

/* Test.p */
USING Demo.Cust.
Demo.cust:StaticProp = "Testing".

MESSAGE Demo.Cust:StaticProp
    VIEW-AS ALERT-BOX INFO BUTTONS OK.

Example #2

USING System.IO.Path FROM ASSEMBLY.

DEFINE VARIABLE cFileName AS CHARACTER NO-UNDO. 

cFileName = System.IO.Path:Combine(System.IO.Path:GetTempPath(), STRING (GUID) + '.xlsx') .

MESSAGE cFileName 
     VIEW-AS ALERT-BOX.

Example #3

BLOCK-LEVEL ON ERROR UNDO, THROW.

CLASS CreditLimit: 
    
    DEFINE PUBLIC STATIC PROPERTY Test AS CreditLimit
    GET:
        IF NOT VALID-OBJECT(Test)
        THEN ASSIGN Test = NEW CreditLimit().
        RETURN Test.
    END GET.
    SET.
 
END CLASS.