Infinite loop in code raising FIND-FAILED event

Code using the ProDataSet FIND-FAILED event deliberately creates a record in the callback procedure that does not satisfy the WHERE clause of the FIND statement, in order to demonstrate how such a coding error may be handled. Rather than raising a trappable error, the code goes into an infinite loop.

Feb 1, 2016
Knowledge

Title

URL Name

Infinite-loop-in-code-raising-FIND-FAILED-event

Article Number

000117237

Environment

Product: OpenEdge Version: 10.x, 11.x OS: All supported platforms

Question/Problem Description

** <temp-table name> record is not on file. (138)

Code is similar to:

/****************************************************************************/
/* Procedure TT */

DEFINE TEMP-TABLE ttCustomer NO-UNDO
FIELD CustNum AS INTEGER
FIELD NAME AS CHARACTER

INDEX iCN
IS PRIMARY
UNIQUE CustNum
.

/****************************************************************************/
/* Procedure PDS Def */

DEFINE DATASET pdsCustomer
FOR ttCustomer
.

/****************************************************************************/
/* Procedure Variables */

DEFINE VARIABLE iCnt AS INTEGER NO-UNDO.
DEFINE VARIABLE iLoop AS INTEGER NO-UNDO.

/****************************************************************************/
/* Initialize */

BUFFER ttCustomer:SET-CALLBACK-PROCEDURE ("find-failed", "FindCustomer").

ASSIGN
/*
"iCnt = 0" works as intended: on each iteration of the DO loop the
temp-table record is not found, so the callback procedure creates one.
*/
/* iCnt = 0 */
/*
"iCnt =1" deliberately introduces an error: a different record is
created than the one for which the FIND is looking. The callback executes
over and over infinitely.
*/
iCnt = 1
.

/****************************************************************************/
/* Do Work */

MESSAGE "start"
VIEW-AS ALERT-BOX.

DO iLoop = 1 TO 10:

FIND ttCustomer
WHERE ttCustomer.CustNum = iLoop
EXCLUSIVE-LOCK
NO-ERROR
.
IF ERROR-STATUS:ERROR OR ERROR-STATUS:NUM-MESSAGES > 1
THEN MESSAGE 'TRAPPED' ERROR-STATUS:GET-MESSAGE (1) VIEW-AS ALERT-BOX.

END.

MESSAGE "FIND loop complete"
VIEW-AS ALERT-BOX.

FOR EACH ttCustomer
NO-LOCK
:

DISPLAY ttCustomer
WITH DOWN
.

END.

MESSAGE "Done"
VIEW-AS ALERT-BOX.

/****************************************************************************/
PROCEDURE FindCustomer:
/****************************************************************************/
/* Local Parameters */

DEFINE INPUT PARAMETER DATASET FOR pdsCustomer.

/****************************************************************************/

ASSIGN
iCnt = iCnt + 1
.

CREATE ttCustomer.
ASSIGN
ttCustomer.CustNum = iCnt
ttCustomer.NAME = STRING(NOW)
.

/*
RETURN NO-APPLY is the usual way to end a FIND-FAILED callback procedure.
It allows the FIND to be re-executed as though the error had never taken place.
*/
RETURN NO-APPLY.
/*
If NO-APPLY is removed from the RETURN statement, the code does not loop and
all new records are displayed.
*/
/* RETURN. */

END PROCEDURE.

Steps to Reproduce

Clarifying Information

If NO-APPLY is removed from the callback procedure RETURN statement, the code does not loop and all temp-table records are displayed. Note that this is not the usual way to code a FIND-FAILED callback procedure.

Error Message

Defect Number

Defect PSC00344813

Enhancement Number

Cause

This is expected behavior. The purpose of ending a FIND-FAILED callback procedure with RETURN NO-APPLY is to allow the FIND statement to be re-executed as though the error had never taken place. In this case, the code was deliberately written incorrectly so that a record satisfying the FIND is not created in the callback procedure. Therefore, when the FIND statement is executed again it continues to fail, and the code loops infinitely.

Defect PSC00344813 was opened to clarify the documentation in this regard.

Resolution

A coding error like the one in the example cannot be trapped. In a real FIND-FAILED callback procedure, be sure to retrieve or create the missing record within the callback procedure. End the procedure with RETURN NO-APPLY so the FIND can be retried.

Workaround

Notes

References to Other Documentation:

OpenEdge Development: ABL Reference, "Handle-based Object Events Reference > Event tables > ProDataSet events > FIND-FAILED event"
OpenEdge Development: ProDataSets, Chapter 7, "Advanced Events and Attributes > ProDataSet buffer FIND-FAILED event"

Keyword Phrase

Last Modified Date

2/18/2017 12:16 AM

Infinite loop in code raising FIND-FAILED event

Files(1)

Was this article helpful?

Was this article helpful?

Infinite loop in code raising FIND-FAILED event

Information

Related Articles