BUFFER parameter for a PROTECTED TEMP-TABLE or DATASET in a sub-class causes the session to crash

Using BUFFER parameters on a table in a PROTECTED TEMP-TABLE or DATASET in a sub-class causes various different runtime errors when instantiating the instance, depending on the structure of the code.

In some cases, the code work as expected, but in other cases the AVM terminates with a session failure.

The following test cases demonstrate:

Preparation:

1. Base class:

CLASS Base: 

    DEFINE PROTECTED TEMP-TABLE ttCustomer NO-UNDO
        FIELD custNum AS INTEGER 
        FIELD custName AS CHARACTER 
        INDEX custNum IS PRIMARY UNIQUE custnum.

END CLASS.

2. Caller routine (test.p):

DEFINE VARIABLE obj AS SubClass NO-UNDO.

obj = NEW SubClass().

MESSAGE obj VIEW-AS ALERT-BOX.

obj:TestIt().

CATCH e AS Progress.Lang.Error :
    MESSAGE "ERROR Intercepted" SKIP
            "Number of messages:" e:NumMessages SKIP 
            e:GetMessage(1)
    VIEW-AS ALERT-BOX.
END CATCH.

Test Case 1:

1. Create the sub class with  a reference to the temp table in the call:

# SubClass.cls

CLASS SubClass INHERITS Base: 

    METHOD PUBLIC VOID TestIt ():
        TestA(BUFFER  ttCustomer).
    END METHOD.

    METHOD PRIVATE VOID TestA (BUFFER ttCustomer FOR ttCustomer):
        MESSAGE "TestA" VIEW-AS ALERT-BOX.
        RETURN.
    END METHOD .
END CLASS.

  ​Result:  Success.

Test Case 2:

1. Remove the call to TestA() in the TestIt() method of the SubClass as follows:

# SubClass.cls

CLASS SubClass INHERITS Base: 

    METHOD PUBLIC VOID TestIt ():
        /*TestA(BUFFER  ttCustomer).*/
    END METHOD.

    METHOD PRIVATE VOID TestA (BUFFER ttCustomer FOR ttCustomer):
        MESSAGE "TestA" VIEW-AS ALERT-BOX.
        RETURN.
    END METHOD.

END CLASS.

​
Result:  Session failure when executing "obj = NEW SubClass()." in test.p

Test Case 3:

1. Amend the sub class with a reference to the temp table (ttCustomer) in the definition for the buffer (bCust ):

#  SubClass.cls

CLASS SubClass INHERITS Base: 

    METHOD PUBLIC VOID TestIt ():
        /*TestA(BUFFER  ttCustomer).*/
    END METHOD.

    METHOD PRIVATE VOID TestA (BUFFER ttCustomer FOR ttCustomer):
        DEFINE BUFFER bCust FOR ttCustomer.
        MESSAGE "TestA" VIEW-AS ALERT-BOX.
        RETURN.
    END METHOD .

END CLASS.

Test Case 1: works because there is a reference to the temp-table in the call, which passes the default buffer for the temp table.

Test Case 3: works because there is a reference to the temp-table in the definition for the buffer:
The failure occurs in Test Case 2, because the only reference to the temp-table is in the sub class, is in the parameter. Because the name of the buffer parameter is ttCustomer (the same as the table) the use of this in the method will not count as a reference to the temp-table.

If the only reference to a temp table is as a buffer parameter to a method in a sub class, the run time will be unable to locate the temp table at instantiation time resulting in a crash. A slight variation of the above can also result in error 566 instead of a crash. For further clarification, refer to Article  Using BUFFER parameters on a table in a PROTECTED TEMP-TABLE or DATASET in a sub-class causes error 566.  

Upgrade to OpenEdge 11.6 or use the workaround below.

There are several workarounds to consider:

1. Change the name and reference the temp table:

For example:

METHOD PRIVATE VOID TestA (BUFFER ttpb FOR ttCustomer):
    MESSAGE "TestA"
    VIEW-AS ALERT-BOX.

    MESSAGE buffer ttCustomer:name.

    RETURN.

END METHOD.

2. Ensure that there is a reference to the temp table in the class if a buffer parameter is used for it with a method.

3. Make the temp-table in the base class private and define it again in the sub class. Then pass the temp-table as a parameter to the sub class.

This workaround needs to carry two copies of the temp-table, which consumes additional resources and can have a performance impact particularly in cases where the dataset is large and runs the risk of the content getting out of sync.

Progress Article: 

Using BUFFER parameters on a table in a PROTECTED TEMP-TABLE or DATASET in a sub-class causes error 566.