How to monitor for an AI FULL condition if you aren't using ai management?
The attached code provides the ability to monitor the ai files attached to a specific database on a specified interval to determine whether they're full and more ai space is required.
 

FUNCTION getTimestamp RETURNS DATETIME ( INPUT pcDateString AS CHARACTER ):
    DEFINE VARIABLE iDay        AS INTEGER     NO-UNDO.
    DEFINE VARIABLE iMonth      AS INTEGER     NO-UNDO.
    DEFINE VARIABLE iYear       AS INTEGER     NO-UNDO.
    DEFINE VARIABLE iHour       AS INTEGER     NO-UNDO.
    DEFINE VARIABLE iMinute     AS INTEGER     NO-UNDO.
    DEFINE VARIABLE iSecond     AS INTEGER     NO-UNDO.
    
    DEFINE VARIABLE cDateString AS CHARACTER   NO-UNDO.
    DEFINE VARIABLE cTime       AS CHARACTER   NO-UNDO.
    DEFINE VARIABLE cMonths     AS CHARACTER   NO-UNDO
        INITIAL "Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec".
    
    DEFINE VARIABLE dtTimestamp AS DATETIME    NO-UNDO.
    
    IF (pcDateString GT "") NE TRUE        OR 
       NOT (pcDateString BEGINS "Start: ") OR
       INDEX(pcDateString,"N/A") GT 0 THEN
        RETURN ?.
    
    ASSIGN cDateString = TRIM(SUBSTRING(pcDateString,
                                        INDEX(pcDateString,":") + 1))
           iMonth      = INTEGER(LOOKUP(ENTRY(2,cDateString," "),
                                        cMonths))
           iDay        = INTEGER(ENTRY(3,cDateString," "))
           cTime       = ENTRY(4,cDateString," ")
           iHour       = INTEGER(ENTRY(1,cTime,":"))
           iMinute     = INTEGER(ENTRY(2,cTime,":"))
           iSecond     = INTEGER(ENTRY(3,cTime,":"))
           iYear       = INTEGER(ENTRY(NUM-ENTRIES(cDateString," "),
                                       cDateString,
                                       " "))
           dtTimestamp = DATETIME(iMonth,iDay,iYear,iHour,iMinute,iSecond).
           
   RETURN dtTimestamp.
           
END FUNCTION.

DEFINE TEMP-TABLE ttExtent NO-UNDO
    FIELD tiExtentNum AS INTEGER    LABEL "Extent No" FORMAT "zzz9"
    FIELD tcStatus    AS CHARACTER  LABEL "Status"
    FIELD tlFixed     AS LOGICAL    LABEL "Fixed Extent"
    FIELD tiSize      AS INT64      LABEL "Size"
    FIELD tdtStart    AS DATETIME   LABEL "Timestamp"
    FIELD tiExtSeq    AS INTEGER    LABEL "Extent Sequence"
    FIELD tcExtPath   AS CHARACTER  LABEL "Extent Path"
    INDEX idxExtent IS PRIMARY UNIQUE tiExtentNum tiExtSeq tdtStart.
    
DEFINE VARIABLE fiInterval   AS INTEGER     NO-UNDO INITIAL 30.

DEFINE VARIABLE fiDatabase   AS CHARACTER   NO-UNDO.
DEFINE VARIABLE gcSlash      AS CHARACTER   NO-UNDO.
DEFINE VARIABLE gcDLC        AS CHARACTER   NO-UNDO.

DEFINE VARIABLE glStop       AS LOGICAL     NO-UNDO.

DEFINE BUTTON btnSearchDB LABEL "Select DB".

DEFINE BUTTON btnStart    LABEL "Start Monitoring".
DEFINE BUTTON btnStop     LABEL "Stop Monitoring".

DEFINE QUERY qExtent FOR ttExtent SCROLLING.

DEFINE BROWSE bExtent QUERY qExtent 
    DISPLAY ttExtent
    WITH 8 DOWN WIDTH 75.
    
DEFINE FRAME fExtent 
    fiDatabase VIEW-AS FILL-IN SIZE 
                      &IF "{&OPSYS}" EQ "WIN32" &THEN 
                          50 
                      &ELSE 
                          55 
                      &ENDIF
                       BY 1 
               FORMAT "x(255)" LABEL "Database"
               COLON 14
    &IF "{&OPSYS}" EQ "WIN32" &THEN
        btnSearchDB
    &ELSE &ENDIF 
      SKIP
    fiInterval VIEW-AS FILL-IN SIZE 8 BY 1 
               FORMAT "zzzzz9" 
               LABEL "Interval between tests (in seconds)" SKIP(1)
    bExtent SKIP(1)
    btnStart AT 45 btnStop
    WITH SIDE-LABELS THREE-D NO-BOX.
    
&IF "{&OPSYS}" EQ "WIN32" &THEN
ON CHOOSE OF btnSearchDB IN FRAME fExtent DO:
    DEFINE VARIABLE cDatabase   AS CHARACTER   NO-UNDO.

    SYSTEM-DIALOG GET-FILE cDatabase
        FILTERS "OpenEdge Database (*.db) files"    "*.db",
                "All File(s) (*.*)"                 "*.*"
        DEFAULT-EXTENSION "*.db"
        TITLE "Select Database ...".
    
    FILE-INFO:FILE-NAME = cDatabase.
    IF FILE-INFO:FULL-PATHNAME EQ ? THEN
        RETURN.
        
    fiDatabase:SCREEN-VALUE IN FRAME fExtent = cDatabase.
END.
&ELSE &ENDIF 

ON CHOOSE OF btnStart IN FRAME fExtent DO:
    FILE-INFO:FILE-NAME = fiDatabase:SCREEN-VALUE.
    IF FILE-INFO:FULL-PATHNAME EQ ? THEN DO:
        MESSAGE "Specify a valid database location"
            VIEW-AS ALERT-BOX ERROR BUTTONS OK.
        LEAVE.
    END.
    
    
    RUN startMonitoring ( INPUT fiDatabase:SCREEN-VALUE IN FRAME fExtent ).
END.

ON CHOOSE OF btnStop IN FRAME fExtent DO:
    glStop = TRUE.
    APPLY "U1" TO THIS-PROCEDURE.
END.

&IF "{&OPSYS}" = "WIN32" &THEN
    GET-KEY-VALUE SECTION "Startup" KEY "DLC" VALUE gcDLC.
&ELSE
    gcDLC = OS-GETENV("DLC").
&ENDIF

gcSlash = (IF OPSYS EQ "Win32" THEN "~\" ELSE "/").
gcDLC = RIGHT-TRIM(gcDLC,gcSlash).

SESSION:MULTITASKING-INTERVAL = 100.

ENABLE ALL WITH FRAME fExtent.
WAIT-FOR CLOSE OF THIS-PROCEDURE.

PROCEDURE startMonitoring:
    DEFINE INPUT  PARAMETER pcDatabase   AS CHARACTER   NO-UNDO.
    
    DEFINE BUFFER bfExtent FOR ttExtent.
    
    REPEAT:
        RUN cleanUp.
    
        RUN checkFull ( INPUT pcDatabase ).
        OPEN QUERY qExtent FOR EACH ttExtent.
        
        FIND FIRST bfExtent WHERE bfExtent.tcStatus EQ "BUSY" NO-LOCK NO-ERROR.
        REPOSITION qExtent TO ROWID ROWID(bfExtent).
        
        IF RETURN-VALUE EQ "AllFull" THEN DO:
            RUN sendNotification 
                ( INPUT "All AI extents are currently full or busy.  Please intervene!" ).
            NEXT.
        END.
        
        WAIT-FOR "u1" OF THIS-PROCEDURE PAUSE 10.
        PROCESS EVENTS.
        IF glStop THEN
            RETURN.
    END.
END PROCEDURE.

PROCEDURE checkFull:
    DEFINE INPUT  PARAMETER pcDatabase   AS CHARACTER   NO-UNDO.
    
    DEFINE VARIABLE iExtent     AS INTEGER     NO-UNDO.
    
    DEFINE VARIABLE cStatus     AS CHARACTER   NO-UNDO.
    DEFINE VARIABLE cInput      AS CHARACTER   NO-UNDO.
    DEFINE VARIABLE cPath       AS CHARACTER   NO-UNDO.
    
    DEFINE VARIABLE lFixed      AS LOGICAL     NO-UNDO.
    
    DEFINE VARIABLE iSize       AS INT64       NO-UNDO.
    
    DEFINE VARIABLE dtTimestamp AS DATETIME    NO-UNDO.
    
    DEFINE BUFFER btExtent FOR ttExtent.
    
    OS-COMMAND SILENT VALUE(gcDLC + gcSlash + 
                            "bin" + gcSlash + "rfutil ~"" + 
                            pcDatabase + "~" -C aimage list > ai.txt").
    INPUT FROM ai.txt.
    REPEAT:
        IMPORT UNFORMATTED cInput.
        cInput = TRIM(cInput).
        
        IF cInput BEGINS "Extent: " THEN
            iExtent = INTEGER(TRIM(ENTRY(2,cInput,":"))).
            
        IF cInput BEGINS "Status: " THEN
            cStatus = TRIM(ENTRY(2,cInput,":")).
        
        IF cInput BEGINS "Type: " THEN
            lFixed = (TRIM(ENTRY(2,cInput,":")) EQ "Fixed Length").
        
        IF cInput BEGINS "Path: " THEN
            cPath = TRIM(REPLACE(cInput,"Path:","")).
            
        IF cInput BEGINS "Size: " THEN
            iSize = INT64(TRIM(ENTRY(2,cInput,":"))).
            
        IF cInput BEGINS "Start: " THEN
            dtTimestamp = getTimestamp(cInput).
            
        IF cInput BEGINS "Seqno: " THEN DO:
            CREATE btExtent.
            ASSIGN btExtent.tiExtentNum = iExtent
                   iExtent              = ?
                   btExtent.tcStatus    = cStatus
                   cStatus              = ?
                   btExtent.tlFixed     = lFixed
                   lFixed               = ?
                   btExtent.tcExtPath   = cPath
                   cPath                = ?
                   btExtent.tiSize      = iSize
                   iSize                = ?
                   btExtent.tdtStart    = dtTimestamp
                   dtTimestamp          = ?
                   btExtent.tiExtSeq    = INTEGER(TRIM(ENTRY(2,cInput,":"))).
        END.
    END.
    INPUT CLOSE.
    
    FIND FIRST btExtent WHERE btExtent.tcStatus EQ "EMPTY" NO-LOCK NO-ERROR.
    IF NOT AVAILABLE btExtent THEN
        RETURN "AllFull".
        
END PROCEDURE.

PROCEDURE cleanUp:
    EMPTY TEMP-TABLE ttExtent.
    OS-DELETE VALUE("ai.txt").
END PROCEDURE.

PROCEDURE sendNotification:
    DEFINE INPUT  PARAMETER pcMessage AS CHARACTER   NO-UNDO.
    
    MESSAGE pcMessage
        VIEW-AS ALERT-BOX WARNING BUTTONS OK.
END PROCEDURE.