When the buffer of a dynamically created TEMP-TABLE object is added to a dynamically created proDataSet, and then subsequently when the DATASET is deleted, the TEMP-TABLE gets deleted along with the DATASET.
Even if the variable for the TEMP-TABLE is scoped to a higher point than where the DATASET is deleted, the TEMP-TABLE gets deleted and can no longer be used.

The following code demonstrates this behavior:

DEFINE VARIABLE hTT AS HANDLE      NO-UNDO.
DEFINE VARIABLE hTB AS HANDLE      NO-UNDO.
DEFINE VARIABLE hDs AS HANDLE      NO-UNDO.

RUN createObjects ( OUTPUT DATASET-HANDLE hDs ).
MESSAGE "Temp table was" + (IF VALID-HANDLE(hTT) THEN " not" ELSE "") +
        " destroyed!"
    VIEW-AS ALERT-BOX INFORMATION BUTTONS OK.

PROCEDURE createObjects:
    DEFINE OUTPUT PARAMETER DATASET-HANDLE phDataset.
    
    DEFINE VARIABLE iCt AS INTEGER     NO-UNDO.
    
    CREATE TEMP-TABLE hTT.
    hTT:ADD-NEW-FIELD("f1","character",0,?,?,"Field 1","Field 1").
    hTT:ADD-NEW-FIELD("f2","integer",0,?,?,"Field 2","Field 2").
    hTT:ADD-NEW-FIELD("f3","character",0,?,?,"Field 3","Field 3").
    hTT:UNDO = FALSE.
    
    hTT:TEMP-TABLE-PREPARE("tt1").
    hTB = hTT:DEFAULT-BUFFER-HANDLE.
        
    CREATE DATASET phDataset.
    phDataset:ADD-BUFFER(hTB).
        
    DO iCt = 1 TO 5:
        hTB:BUFFER-CREATE().
        ASSIGN hTB:BUFFER-FIELD("f1"):BUFFER-VALUE = STRING(iCt)
               hTB:BUFFER-FIELD("f2"):BUFFER-VALUE = iCt
               hTB:BUFFER-FIELD("f3"):BUFFER-VALUE = 
                           hTB:BUFFER-FIELD("f1"):BUFFER-VALUE + ":" +
                           hTB:BUFFER-FIELD("f2"):BUFFER-VALUE.
    END.

    FINALLY:
        DELETE OBJECT phDataset NO-ERROR.
    END FINALLY.
END PROCEDURE.

 

This is expected behavior.  By default when a buffer in a DATASET belongs to a dynamic TEMP-TABLE, its AUTO-DELETE attribute is set to TRUE. 

If you do not want a dynamically created TEMP-TABLE which has been added to a dynamic DATASET or a DATASET-HANDLE parameter variable to be deleted along with the DATASET, assign the buffer's AUTO-DELETE attribute to FALSE.

Note: For AUTO-DELETE to be set the buffer must already have been added to a dataset.  Trying to query or set the AUTO-DELETE attribute is ineffectual if the buffer is NOT already a member of a DATASET.
 

DEFINE VARIABLE hTT AS HANDLE      NO-UNDO.
DEFINE VARIABLE hTB AS HANDLE      NO-UNDO.
DEFINE VARIABLE hDs AS HANDLE      NO-UNDO.

RUN createObjects ( OUTPUT DATASET-HANDLE hDs ).
MESSAGE "Temp table was" + (IF VALID-HANDLE(hTT) THEN " not" ELSE "") +
        " destroyed!"
    VIEW-AS ALERT-BOX INFORMATION BUTTONS OK.

PROCEDURE createObjects:
    DEFINE OUTPUT PARAMETER DATASET-HANDLE phDataset.
    
    DEFINE VARIABLE iCt AS INTEGER     NO-UNDO.
    
    CREATE TEMP-TABLE hTT.
    hTT:ADD-NEW-FIELD("f1","character",0,?,?,"Field 1","Field 1").
    hTT:ADD-NEW-FIELD("f2","integer",0,?,?,"Field 2","Field 2").
    hTT:ADD-NEW-FIELD("f3","character",0,?,?,"Field 3","Field 3").
    hTT:UNDO = FALSE.
    
    hTT:TEMP-TABLE-PREPARE("tt1").
    hTB = hTT:DEFAULT-BUFFER-HANDLE.
        
    CREATE DATASET phDataset.
    phDataset:ADD-BUFFER(hTB).
    hTB:AUTO-DELETE = FALSE.
    
    DO iCt = 1 TO 5:
        hTB:BUFFER-CREATE().
        ASSIGN hTB:BUFFER-FIELD("f1"):BUFFER-VALUE = STRING(iCt)
               hTB:BUFFER-FIELD("f2"):BUFFER-VALUE = iCt
               hTB:BUFFER-FIELD("f3"):BUFFER-VALUE = 
                           hTB:BUFFER-FIELD("f1"):BUFFER-VALUE + ":" +
                           hTB:BUFFER-FIELD("f2"):BUFFER-VALUE.
    END.

    FINALLY:
        DELETE OBJECT phDataset NO-ERROR.
    END FINALLY.
END PROCEDURE.