In OpenEdge 12 the default action after an error is caught in a FOR EACH block is NEXT, not RETRY.  This causes a query to skip groups of records during a FOR EACH with a BREAK BY, when an ERROR is raised/caught.

The following issues can happen if you have a FOR EACH loop with a CATCH block after an error is caught by that catch block:

• If you have a BREAK BY clause, records in the current break group get skipped after an error is handled
• If a statement with I/O interaction, such as UPDATE, is executed, or if there is a reference to the RETRY function, the default ‘retry’ behavior will not happen, and you will get the next record, if any.

Run the below code to reproduce (in 12.0 or later).  This demonstrates that, when an error is raised, the query skips forward 3 records.

BLOCK-LEVEL ON ERROR UNDO, THROW.

DEFINE TEMP-TABLE tt
	FIELD Country AS CHARACTER
	FIELD Customer AS CHARACTER
	INDEX Country Country
	INDEX Customer Customer.

CREATE tt.
ASSIGN tt.Country = "Sweden"
       tt.Customer = "CGI".
	   
CREATE tt.
ASSIGN tt.Country = "Sweden"
       tt.Customer = "ABB".
	   
CREATE tt.
ASSIGN tt.Country = "Sweden"
       tt.Customer = "Progress".
	   
CREATE tt.
ASSIGN tt.Country = "US"
       tt.Customer = "CGI".
	   
CREATE tt.
ASSIGN tt.Country = "US"
       tt.Customer = "Progress".


FOR EACH tt BREAK BY tt.Country BY tt.Customer:

    MESSAGE "Loop at" tt.Country tt.Customer VIEW-AS ALERT-BOX.
    IF FIRST-OF(tt.Country) THEN 
	    MESSAGE "First of" tt.Country tt.Customer VIEW-AS ALERT-BOX.
		
    RUN Validation.

    IF LAST-OF(tt.Country) THEN 
	    MESSAGE "Last of" tt.Country tt.Customer VIEW-AS ALERT-BOX.


    // Here we don't want the standard solution to return validation errors to frontend with return error.
    // Instead we catch the errors and continue the loop
    CATCH e AS Progress.Lang.Error :
        IF RETURN-VALUE > "" OR 
	       e:GetMessage(1) > "" THEN DO:
            MESSAGE "ERROR!" RETURN-VALUE e:GetMessage(1) VIEW-AS ALERT-BOX.
        END.
    END CATCH.

END.

PROCEDURE Validation:
RETURN ERROR SUBSTITUTE("Error found on &1 &2", tt.Country, tt.Customer).
END PROCEDURE.

Note that the above code sorts first on Country then on Company.  The code hits the first message for the first Country Company record "Loop at Sweden ABB":


Next hits the message in the FIRST-OF condition:


The Validation program runs (e.g. RUN Validation) and returns an ERROR, resulting in the below message.


Then we skip Sweden CGI, Sweden Progress, directly to the next full break group:

 

In OpenEdge 12 the default action after an error is caught in a FOR EACH block is NEXT, not RETRY.

This was introduced by the fix to Bug PSC00359423, which changed the error handling behavior of the FOR EACH block, as documented in article History of FOR EACH block error handling behavior changes.
 

Upgrade to OpenEdge Update 12.2.8 or later.

With the fix in place, once the error occurs, the block ends and the query goes to the next record.
 

References to Other Documentation:
Progress Article(s):
For behavior prior to OpenEdge 12 refer to Article  Infinite FOR EACH loop when displaying a .NET message box with a "wait-for"