When the number of fields in an IMPORT DELIMITER statement does not exactly match the number of delimited entries in line of text file, IMPORT DELIMITER reads beyond the current line, concatenating data incorrectly.

When reading an external delimited text file using the IMPORT DELIMITER "," statement, some records are not imported correctly, when an extent array does not exactly match the number of remaining fields in the line of the text file. 

The IMPORT statement is used to import the entire data line into a Temp Table record. In this particular case each data line from textfile.txt contains 551 delimited values.

The temp table import_data structure is such that the first 3 elements are distinct fields, but the fourth field in the temp table is an extent character array of 200 elements.  ABL should read elements 4 to 203 into the extent array and then disregard the remaining fields, but this is not happening.
 

1. Copy attached textfile.txt into the C:\ drive
2. Run below code:

DEFINE TEMP-TABLE import_data NO-UNDO
    FIELD sort_order AS CHARACTER
    FIELD rectable AS CHARACTER
    FIELD rec_type AS CHARACTER
    FIELD rec_data AS CHARACTER EXTENT 200 /* 548 exactly matches number of elements in the line after the first three fields */
    INDEX import_data_x1 IS PRIMARY rec_type sort_order rectable
    INDEX import_data_x2 rectable.

DEF VAR use_write_order AS INTEGER INITIAL 1.
DEF VAR cRecord AS CHARACTER.

OUTPUT TO "C:\results.txt".

/*READ ALL RECORDS FROM THE IMPORT FILE:*/
MESSAGE "Step 1 - Read the data...".
INPUT FROM "textfile.txt".
REPEAT:
    CREATE import_data NO-ERROR.
    IMPORT DELIMITER "," import_data NO-ERROR.

    MESSAGE "rectable=" import_data.rectable "rec_type=" import_data.rec_type "rec_data=" import_data.rec_data[001] "...etc...".
END.
INPUT CLOSE.

MESSAGE " " SKIP(1).
MESSAGE "Step 1 - This is what is in the temp table...".
FOR EACH IMPORT_data:
    MESSAGE "rectable=" import_data.rectable "rec_type=" import_data.rec_type "rec_data=" import_data.rec_data[001] "...etc...".
END.
OUTPUT CLOSE.

Note: This is not limited to Array fields/variables, in fact the below simplified example demonstrates this problem.

• Save the following to testtext.txt
  foo~bar~blah~
  blah~foo~bar~
• Run the below code sample:

  DEFINE TEMP-TABLE ttTest
      FIELD f1 AS CHARACTER
      FIELD f2 AS CHARACTER
      FIELD f3 AS CHARACTER
      FIELD f4 AS CHARACTER.
  
  INPUT FROM testtext.txt.
  REPEAT:
      CREATE ttTest.
      IMPORT DELIMITER "~~" ttTest.
  END.
  INPUT CLOSE.
  
  FOR EACH ttTest:
      DISPLAY ttTest.
  END.

• The values from both lines are imported into one record and the output looks like below:

The exact cause is not known at this time.

Until the fix is available, use the workaround below.

1. Adjust the number of columns in the input to match the number of fields in the data line

or

2. Read in each line using UNFORMATTED and use the ENTRY function with the delimiter to parse the values

DEFINE TEMP-TABLE ttTest 
    FIELD f1 AS CHARACTER
    FIELD f2 AS CHARACTER
    FIELD f3 AS CHARACTER 
    FIELD f4 AS CHARACTER.

DEFINE VARIABLE cInput AS CHARACTER   NO-UNDO.

INPUT FROM testtext.txt.
REPEAT:
    CREATE ttTest.
    IMPORT UNFORMATTED cInput.
    RUN parseLine ( INPUT cInput,
                    INPUT "~~",
                    BUFFER ttTest ).
/*     IMPORT DELIMITER "~~" ttTest. */
    
END.
INPUT CLOSE.

FOR EACH ttTest:
    DISPLAY ttTest.
END.

PROCEDURE parseLine:
    DEFINE INPUT  PARAMETER pcLine      AS CHARACTER   NO-UNDO.
    DEFINE INPUT  PARAMETER pcDelimiter AS CHARACTER   NO-UNDO.
    DEFINE PARAMETER BUFFER ttTest FOR ttTest.
    
    DEFINE VARIABLE iCol  AS INTEGER     NO-UNDO.
    
    DEFINE VARIABLE hBuff AS HANDLE      NO-UNDO.
    DEFINE VARIABLE hCol  AS HANDLE      NO-UNDO.
    
    hBuff = BUFFER ttTest:HANDLE.
    DO iCol = 1 TO NUM-ENTRIES(pcLine,pcDelimiter):
        hCol = hBuff:BUFFER-FIELD(iCol) NO-ERROR.
        /* If the column handle is not valid, this may mean the line
           has more columns than does the buffer, in which case LEAVE */
        IF NOT VALID-HANDLE(hCol) OR
           NOT hBuff:AVAILABLE THEN
            LEAVE.
        
        hCol:BUFFER-VALUE = ENTRY(iCol,pcLine,pcDelimiter).
    END.
END PROCEDURE.