Developers frequently encounter use cases where similar processing must be performed on several different fields of various data types.

While a FOR EACH, PRESELECT or FIND can be transformed into a dynamic query that can be executed many times while varying the WHERE clause (predicate), there is no equivalent construct for comparing or assigning values to database fields that are not known until run time, and that may be of varying types.

In other words, there is no such thing as a "dynamic IF" or "dynamic ASSIGN" in ABL. This can result in bulky code containing multiple IF and CASE statements with largely repetitive code for each branch.

However, if the fields, the logical or assignment operators needed, and the values to be compared or assigned can be stored in an OpenEdge database table, logic similar to a "dynamic IF" or "dynamic ASSIGN" can be coded using dynamic buffers and buffer-field objects.

 

The key a data-driven solution is to store the fields to be operated on, the logical or assignment operators, and the values to be compared or assigned as separate items. They can be represented as separate fields in a table, or as a single field containing one or more "triples" of all three items in a comma-separated list. All three kinds of items, whether in separate fields or in a list, should be represented in string form .The ABL procedure will:

1. Create a dynamic buffer for the table to be operated on.
2. Create a buffer-field object to access the fields in each record.
3. For each triple:
   1. Use the BUFFER-FIELD() method of the buffer handle with the field name as the parameter to access the field with that name.
   2. Get the type of the object using the buffer-field object's TYPE attribute.
   3. If the field is of type CHARACTER, use it as is. For other types, cast the value to the appropriate type in a CASE statement.
   4. Use another CASE statement for the operator string. Each WHEN block will contain the appropriate statement to compare the field to a value or to assign the value to a field.

The following example code assumes that a CHARACTER field named ExclusionElement has been added to the Employee table of the Sports2000 sample database. This field contains a comma-separated list of elements organized into triples:

1. An Employee field to compare
2. The comparison to use (e. g. EQ or LT)
3. A value to compare it to.

If the comparison is TRUE, the employee's record is not displayed. This example processes all seven Employee records in Department 100, but excludes all but one employee (EmpNum 25, Rob Davis).

DEFINE VARIABLE hEmployee AS HANDLE NO-UNDO.
DEFINE VARIABLE iNumEntries AS INTEGER NO-UNDO.
DEFINE VARIABLE iNumExclusions AS INTEGER NO-UNDO.
DEFINE VARIABLE ii AS INTEGER NO-UNDO.
DEFINE VARIABLE ij AS INTEGER NO-UNDO.
DEFINE VARIABLE cExclusionField AS CHARACTER EXTENT 4 NO-UNDO.
DEFINE VARIABLE cExclusionElement AS CHARACTER EXTENT 4 NO-UNDO.
DEFINE VARIABLE cExclusionLogicalOp AS CHARACTER EXTENT 4 NO-UNDO.
DEFINE VARIABLE cExclusionValue AS CHARACTER EXTENT 4 NO-UNDO.
DEFINE VARIABLE lExclude AS LOGICAL NO-UNDO.
DEFINE VARIABLE hBufferField AS HANDLE NO-UNDO.

/* Function prototypes. Separate functions are needed for each logical operator,
as there is no other way to get an operator from the value of an expression.
*/

FUNCTION excludeEQ RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER
    ) FORWARD.

FUNCTION excludeLE RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER
    ) FORWARD.

FUNCTION excludeLT RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER
    ) FORWARD.

FUNCTION excludeNE RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER
    ) FORWARD.

/* Get the buffer handle for the table containing the fields on which records
    will be excluded.
    */
hEmployee = BUFFER Employee:HANDLE.

/* Get the top-level record containing the exclusion elements.
    */
FOR EACH Department WHERE Department.DeptCode = '100' NO-LOCK:

    /* For each exclusion element there will be three entries:
        1. The field to be evaluated
        2. The comparison operator
        3. The value to be excluded
        */
    iNumEntries = NUM-ENTRIES (Department.ExclusionElement).
    iNumExclusions = iNumEntries / 3.
    DO ii = 1 TO iNumEntries BY 3:
        ij = ii / 3 + 1.
        ASSIGN
            cExclusionField[ij] =
                ENTRY(1,ENTRY(ii, Department.ExclusionElement),"[")
            /* If the field reference has an array element, parse that out */
            cExclusionElement[ij] = (IF NUM-ENTRIES(ENTRY(ii,Department.ExclusionElement),"[") GT 1 THEN 
                                         TRIM(ENTRY(2,ENTRY(ii, Department.ExclusionElement),"["),"]")
                                     ELSE "")
            cExclusionLogicalOp[ij] =
                ENTRY (ii + 1, Department.ExclusionElement)
            cExclusionValue[ij] =
                ENTRY (ii + 2, Department.ExclusionElement)
            .
    END.

    /* Evaluate each record for exclusion.
        */
    FOR EACH Employee WHERE Employee.DeptCode = Department.DeptCode NO-LOCK:

        /* Track the current decision state for whether to exclude the
            record. The starting state is not to exclude it.
        */
        lExclude = FALSE.

        /* Evaluate the reoord against each exclusion element.
        */
        DO ii = 1 TO iNumExclusions:

            /* Get the buffer-field handle for the field to evaluate.
            */
            hBufferField = hEmployee:BUFFER-FIELD(cExclusionField[ii]).

            /* Evaluate the field using the function for the logical operator
                in the exclusion element. Each function takes the buffer-field
                handle as a parameter so the function can determine the type
                type of the field as well as its value. A return value of
                TRUE means the record should be excluded. OR each return value
                with the current state so that if any of the criteria say to
                exclude the record, it will be excluded.
                */
            CASE cExclusionLogicalOp[ii]:
                WHEN '=' THEN
                    lExclude = lExclude OR
                        excludeEQ (hBufferField, cExclusionElement[ii], cExclusionValue[ii]).

                WHEN '<=' THEN
                    lExclude = lExclude OR
                        excludeLE (hBufferField, cExclusionElement[ii], cExclusionValue[ii]).

                WHEN '<' THEN
                    lExclude = lExclude OR
                        excludeLT (hBufferField, cExclusionElement[ii], cExclusionValue[ii]).
                WHEN '<>' THEN
                    lExclude = lExclude OR
                        excludeNE(hBufferField, cExclusionElement[ii], cExclusionValue[ii]).
            END CASE.

        END.

        /* If any of the criteria say to exclude, exclude the record.
        */
        IF lExclude THEN
            NEXT.

        /* Process the records that are not excluded. This example just
            displays them.
            */
        DISPLAY
            hEmployee:BUFFER-FIELD ('EmpNum'):BUFFER-VALUE()
            hEmployee:BUFFER-FIELD ('LastName'):BUFFER-VALUE()
            hEmployee:BUFFER-FIELD ('FirstName'):BUFFER-VALUE()
            .

    END.
END.


FUNCTION excludeEQ RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER ).
    
    DEFINE VARIABLE iElement AS INTEGER     NO-UNDO.

    iElement = (IF (pcExtent GT "") EQ TRUE THEN
                    INTEGER(pcExtent) 
                ELSE 0).
                
    CASE phBufferField:DATA-TYPE:

        WHEN 'CHARACTER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) EQ pcValue.

        WHEN 'DATE' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) EQ DATE(pcValue).

        WHEN 'INTEGER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) EQ INTEGER(pcValue).

    END CASE.

    RETURN FALSE.

END FUNCTION.


FUNCTION excludeLE RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER ).

    DEFINE VARIABLE iElement AS INTEGER     NO-UNDO.

    iElement = (IF (pcExtent GT "") EQ TRUE THEN
                    INTEGER(pcExtent) 
                ELSE 0).
                
    CASE phBufferField:DATA-TYPE:

        WHEN 'CHARACTER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) LE pcValue.

        WHEN 'DATE' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) LE DATE(pcValue).

        WHEN 'INTEGER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) LE INTEGER(pcValue).

    END CASE.

    RETURN FALSE.

END FUNCTION.


FUNCTION excludeLT RETURNS LOGICAL (    
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER ).

    DEFINE VARIABLE iElement AS INTEGER     NO-UNDO.

    iElement = (IF (pcExtent GT "") EQ TRUE THEN
                    INTEGER(pcExtent) 
                ELSE 0).
                
    CASE phBufferField:DATA-TYPE:

        WHEN 'CHARACTER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) LT pcValue.

        WHEN 'DATE' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) LT DATE(pcValue).

        WHEN 'INTEGER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) LT INTEGER(pcValue).

    END CASE.

    RETURN FALSE.

END FUNCTION.

FUNCTION excludeNE RETURNS LOGICAL (
    INPUT phBufferField AS HANDLE,
    INPUT pcExtent      AS CHARACTER, 
    INPUT pcValue AS CHARACTER ).

    DEFINE VARIABLE iElement AS INTEGER     NO-UNDO.

    iElement = (IF (pcExtent GT "") EQ TRUE THEN
                    INTEGER(pcExtent) 
                ELSE 0).

    CASE phBufferField:DATA-TYPE:

        WHEN 'CHARACTER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) NE pcValue.

        WHEN 'DATE' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) EQ DATE(pcValue).

        WHEN 'INTEGER' THEN
            RETURN phBufferField:BUFFER-VALUE(iElement) EQ INTEGER(pcValue).

    END CASE.

    RETURN FALSE.

END FUNCTION.

 

 

References to Written Documentation:

Progress Article(s):
How to refer to an extent with BUFFER-VALUE Attribute of a buffer-field object?