How to use automatic transactions to undo a Transaction on a State-free appserver?
 

To undo a transaction from a client connected to a state-free appsever the client must first start an 'automatic transaction' on the appserver by instantiating a persistent procedure with TRANSACTION-MODE AUTOMATIC.  This binds the state-free appserver agent to the client.  Any transactions implemented in the context of that persistent procedure can be rolled back by the client by executing the SET-ROLLBACK() method.  Although it is important to realize that any transactions committed by other state-free appserver agents outside the context of the persistent procedure cannot be rolled back.  For example:

Server side procedure a-txtest.p:
 

/* This statement makes this procedure a transaction-initiating procedure */
TRANSACTION-MODE AUTOMATIC.
PROCEDURE startme: /* This empty internal procedure starts a transaction */
END.

PROCEDURE stopme: /* This internal proc arranges for a commit */
    DEFINE VARIABLE hTrans AS HANDLE.
    hTrans = THIS-PROCEDURE:TRANSACTION.
    htrans:SET-COMMIT().
END.

PROCEDURE abortme: /* This internal proc arranges for a rollback */
    DEFINE VARIABLE hTrans AS HANDLE.
    hTrans = THIS-PROCEDURE:TRANSACTION.
    MESSAGE hTrans:IS-OPEN VIEW-AS ALERT-BOX.
    hTrans:SET-ROLLBACK().
END.

PROCEDURE custupdate:
    FIND FIRST customer EXCLUSIVE-LOCK.
    customer.name = customer.name + "XXXX".
END.


Client side procedure:


DEFINE VARIABLE ph AS HANDLE.

DEFINE VARIABLE h  AS HANDLE NO-UNDO.
CREATE SERVER h.
h:CONNECT("-AppService asBroker1 -H localhost -S 5162 -sessionModel Session-free").

/* Create a transaction initiating procedure and start the transaction */
RUN a-txtest.p ON SERVER h TRANSACTION DISTINCT PERSISTENT SET ph.

RUN custupdate IN ph. /* This update will be rolled back by abort */
RUN abortme IN ph.
DELETE PROCEDURE ph.

If the code that has the TRANSACTION-MODE AUTOMATIC does need to be run as a persistent procedure, which thus binds the ABL Session on the AppServer to a specific client.