Traditional error handling shows ERROR-STATUS:ERROR is not true when an error was raised and NO-ERROR was used.

Under traditional / unstructured error handling (not based on Exceptions) shows ERROR-STATUS:ERROR is not true when an error was raised. This can leave error conditions raised during NO-ERROR operation to go unnoticed.

29 Apr 2015
Knowledge

Title

URL Name

000022070

Article Number

000157593

Environment

Product: Progress Version: 9.x Product: OpenEdge Version: 10.x, 11.x, 12.x OS: All supported platforms

Question/Problem Description

ERROR-STATUS:ERROR not TRUE when an error was raised.
Function or method invoked with NO-ERROR qualifier.
Errors occur but ERROR-STATUS:ERROR attribute not set to TRUE.
Error messages shown if same method / function invoked without NO-ERROR.

ERROR-STATUS:ERROR remains FALSE even if an error was raised.

Error was raised and ERROR-STATUS:ERROR was not set to TRUE.
Not every runtime-error can be treated with ERROR-STATUS:ERROR condition.
ERROR-STATUS:ERROR cannot capture all errors on an object reliably.

Error handling build on condition ERROR-STATUS:ERROR might miss raised error. It is not possible to enumerate the cases where NO-ERROR will fail to set ERROR-STATUS or where it will fail to suppress error messages.

Steps to Reproduce

Clarifying Information

Following code shows the issue:

DEFINE VARIABLE cXMLSource AS CHARACTER.
DEFINE TEMP-TABLE ttExample

FIELD abc AS CHARACTER
INDEX Prima IS PRIMARY abc.

PROCEDURE showErrorMessages:
    DEFINE VARIABLE i AS INTEGER NO-UNDO. 

    DO i = 1 TO ERROR-STATUS:NUM-MESSAGES :
      MESSAGE
        ERROR-STATUS:GET-MESSAGE (i)
        VIEW-AS ALERT-BOX.
      END.
END PROCEDURE.

cXMLSource = 'C:\denyWriteXml.xml'.
/* cXMLSource has a write-protection and WRITE-XML causes the error: */
/* Invalid encoding for WRITE-XML. (13515)                           */

Main:
DO ON ERROR UNDO Main, LEAVE Main:
/*DO ON ERROR UNDO, THROW:*/

    TEMP-TABLE ttExample:HANDLE:WRITE-XML ( 'file':U,
                                             cXMLSource,
                                             YES,  /* formatted           */
                                             ?,    /* encoding            */
                                             ?,    /* schema-location     */
                                             NO,   /* write-xmlschema     */
                                             NO,   /* min-xmlschema       */
                                             YES) NO-ERROR. /* write-before-image  */
END.  /* Main */

IF ERROR-STATUS:ERROR THEN RUN showErrorMessages. /*not recommended condition to test if error was raised*/
.

case 1: UNDO LEAVE + NO-ERROR with ERROR-STATUS:ERROR => does not catch the error
case 2: UNDO THROW + NO-ERROR with ERROR-STATUS:ERROR => catches the error

In addition, ERROR-STATUS:NUM-MESSAGES will be > 0 when AVM itself raises an error message, but not when the ABL code raises an error condition with RETURN ERROR:

PROCEDURE raiseerror:
    RETURN ERROR "no can do".
END.

RUN raiseerror NO-ERROR.

PROCEDURE showErrorMessages:
    DEFINE VARIABLE i AS INTEGER NO-UNDO. 

    DO i = 1 TO ERROR-STATUS:NUM-MESSAGES :
      MESSAGE
        ERROR-STATUS:GET-MESSAGE (i)
        VIEW-AS ALERT-BOX.
      END.
END PROCEDURE.

IF ERROR-STATUS:ERROR THEN RUN showErrorMessages. /*not recommended condition to test if error was raised*/

Error Message

Defect Number

Enhancement Number

Cause

This is expected behaviour.

Section from ON ERROR phrase ABL documentation:

For callable blocks, including procedures, user-defined functions, class-based methods, and property accessors use the ROUTINE-LEVEL ON ERROR phrase. All of these blocks have a default ON ERROR setting of UNDO, LEAVE.

ABL handle methods treat errors as warnings and do not raise error, unless the block containing the code uses a CATCH block. To check for handle method errors in blocks without CATCH, use the NO-ERROR option and check ERROR-STATUS:NUM-MESSAGES for a value greater than zero (0). For handle methods, ERROR-STATUS:ERROR is not set.

It is not possible to enumerate the cases where NO-ERROR will fail to set ERROR-STATUS or where it will fail to suppress error messages, and likewise for when it does set them from within an expression. These are cases that come up ad-hoc, sometimes from third parties and sometimes from unusual transaction conditions and cannot be documented or even predicted exhaustively.

Resolution

One of the solutions is to use ERROR-STATUS:NUM-MESSAGES as well as ERROR-STATUS:ERROR.
Combined with GET-NUMBER() and GET-MESSAGE(), the programmer can trap the errors that may arise. The documentation was updated to reflect this in OpenEdge 10.1B or later releases.

Following code shows one of many cases where only ERROR-STATUS:NUM-MESSAGES is set:

DEFINE VARIABLE hServer AS HANDLE NO-UNDO.

CREATE SERVER hServer.

/* to prove errors do occur */
hServer:CONNECT("-AppService Idontexist").

/* now trap the error */
hServer:CONNECT("-AppService Idontexist") NO-ERROR.

/* error-status:error returns "no" */
MESSAGE "ERROR-STATUS:ERROR: " ERROR-STATUS:ERROR VIEW-AS ALERT-BOX INFO BUTTONS OK.

/* NUM-MESSAGES is set correctly */
MESSAGE "ERROR-STATUS:NUM-MESSAGES : " ERROR-STATUS:NUM-MESSAGES SKIP
        "ERROR-STATUS:GET-NUMBER(1): " ERROR-STATUS:GET-NUMBER(1) VIEW-AS ALERT-BOX.

In this case the NO-ERROR has correctly trapped the error that the second hServer:CONNECT() method has raised however the ERROR-STATUS:ERROR returns a value of false.

Following is an example how to reliable check for errors using the NO-ERROR option and checking both ERROR-STATUS:ERROR and ERROR-STATUS:NUM-MESSAGES:

DEFINE VARIABLE cXMLSource AS CHARACTER.
DEFINE TEMP-TABLE ttExample

FIELD abc AS CHARACTER
INDEX Prima IS PRIMARY abc.

PROCEDURE showErrorMessages:
    DEFINE VARIABLE i AS INTEGER NO-UNDO. 

    DO i = 1 TO ERROR-STATUS:NUM-MESSAGES :
      MESSAGE
        ERROR-STATUS:GET-MESSAGE (i)
        VIEW-AS ALERT-BOX.
      END.
END PROCEDURE.


cXMLSource = 'C:\denyWriteXml.xml'.
/* "C:\denyWriteXml.xml" should be a read-only file on the filesystem, so it
   will trigger error condition */

Main:
DO ON ERROR UNDO Main, LEAVE Main:

    TEMP-TABLE ttExample:HANDLE:WRITE-XML ( 'file':U,
                                             cXMLSource,
                                             YES,  /* formatted           */
                                             ?,    /* encoding            */
                                             ?,    /* schema-location     */
                                             NO,   /* write-xmlschema     */
                                             NO,   /* min-xmlschema       */
                                             YES) NO-ERROR. /* write-before-image  */
END.  /* Main */

IF (ERROR-STATUS:ERROR = YES OR ERROR-STATUS:NUM-MESSAGES > 0) THEN RUN showErrorMessages.

Starting with OpenEdge 10.1C, other option is to use Structured Error Handling / using CATCH, FINALLY blocks.

DEFINE VARIABLE cXMLSource AS CHARACTER.
DEFINE TEMP-TABLE ttExample

FIELD abc AS CHARACTER
INDEX Prima IS PRIMARY abc.

cXMLSource = 'C:\denyWriteXml.xml'.
/* "C:\denyWriteXml.xml" should be a read-only file on the filesystem, so it
   will trigger error condition */

Main:
DO  ON ERROR UNDO , THROW:

    TEMP-TABLE ttExample:HANDLE:WRITE-XML ( 'file':U,
                                             cXMLSource,
                                             YES,  /* formatted           */
                                             ?,    /* encoding            */
                                             ?,    /* schema-location     */
                                             NO,   /* write-xmlschema     */
                                             NO,   /* min-xmlschema       */
                                             YES). /* write-before-image  */
END.  /* Main */

CATCH anyErrorObject AS Progress.Lang.Error:
    MESSAGE
       anyErrorObject:GetMessage(1)
    VIEW-AS ALERT-BOX.
END CATCH.

FINALLY:
    MESSAGE
       'after Main-Block' 
    VIEW-AS ALERT-BOX.
END FINALLY.

Workaround

Notes

References to Other Documentation:

OpenEdge Development, ABL Error Handling, Handling Warnings:
https://docs.progress.com/bundle/openedge-abl-error-handling-122/page/Handle-warnings.html

OpenEdge Development, Error Handling, Traditional Error Handling:
https://docs.progress.com/bundle/openedge-abl-error-handling-117/page/Traditional-Error-Handling.html

Keyword Phrase

Last Modified Date

6/6/2022 7:59 PM

Traditional error handling shows ERROR-STATUS:ERROR is not true when an error was raised and NO-ERROR was used.

Files(0)

Was this article helpful?

Was this article helpful?

Traditional error handling shows ERROR-STATUS:ERROR is not true when an error was raised and NO-ERROR was used.

Information

Related Articles